Construyendo un árbol de expresiones en Prolog

dcg expression-trees prolog

Pregunta

Estoy buscando una manera de construir un Árbol de Expresión en Prolog. Ya hice algunos experimentos y se me ocurrió el siguiente código de trabajo (que solo manejará las constantes y la expresión más):

const(_).
plus(_, _).

eval(const(R), R).

eval(plus(A, B), R) :- number(A), number(B), R is A+B.
eval(plus(A, B), R) :- number(A), eval(B, B_R), R is A+B_R.
eval(plus(A, B), R) :- eval(A, A_R), number(B), R is A_R+B.
eval(plus(A, B), R) :- eval(A, A_R), eval(B, B_R), R is A_R+B_R.

¿Hay alguna alternativa más simple a este enfoque? ¿Tendré que definir estos 4 casos para cada uno de los operadores que planeo agregar a mi programa?

Respuesta aceptada

Creo que debería hacerlo, aunque no estoy familiarizado con el constructo pred1(pred2(...)...) :- ... (mi Prolog está muy oxidado).

eval(A, A) :- number(A).
eval(plus(A, B), R) :- eval(A, A_R), eval(B, B_R), R is A_R+B_R.

Respuesta popular

Vea aquí otro esquema, explotando DCG y (una especie de) evaluación perezosa:

/*
File:    dcg_calculator.pl
Author:  Carlo,,,
Created: Aug 16 2011
Purpose: associativity and precedences in calculator
*/

:- module(dcg_calculator, [dcg_calculator/2, expr//1]).
%- [library(http/dcg_basics)]. obsolete
:- [library(dcg/basics)].

/* usage

?- dcg_calculator("1+(-2-2)",S),V is S.
S = 1+ (-2-2),
V = -3 ;
false.

*/
dcg_calculator(Formula, IsEvaluable) :-
    phrase(expr(IsEvaluable), Formula, []).

expr(Evaluable) -->
    sum(Evaluable).

sum(S) -->
    product(P), sum_1(P, S).
sum_1(L, S) -->
    "+", product(P), sum_1(L + P, S);
    "-", product(P), sum_1(L - P, S);
    {L = S}.

product(P) -->
    value(V), product_1(V, P).
product_1(V, P) -->
    "*", value(U), product_1(V * U, P);
    "/", value(U), product_1(V / U, P);
    {V = P}.

% value(V) -->
%   {var(V)} -> {V=0 /* between(0, 9, V)*/ }, "0".

value(V) -->
    "(", expr(V), ")" ;
    number(V).

Usar gramáticas para modelar estructuras de datos es una técnica muy útil en Prolog. La gramática utilizada es una implementación de PEG s. La dependencia de SWI-Prolog es muy limitada, solo el número // 1.



Licencia bajo: CC-BY-SA with attribution
No afiliado con Stack Overflow
Licencia bajo: CC-BY-SA with attribution
No afiliado con Stack Overflow