Construire un arbre d'expression en Prolog

dcg expression-trees prolog

Question

Je cherche un moyen de construire un arbre d'expression dans Prolog. J'ai déjà fait quelques expériences et mis au point le code de travail suivant (qui ne gère que les constantes et l'expression plus):

const(_).
plus(_, _).

eval(const(R), R).

eval(plus(A, B), R) :- number(A), number(B), R is A+B.
eval(plus(A, B), R) :- number(A), eval(B, B_R), R is A+B_R.
eval(plus(A, B), R) :- eval(A, A_R), number(B), R is A_R+B.
eval(plus(A, B), R) :- eval(A, A_R), eval(B, B_R), R is A_R+B_R.

Existe-t-il une alternative plus simple à cette approche? Devrai-je définir ces 4 cas pour chacun des opérateurs que je compte ajouter à mon programme?

Réponse acceptée

Je pense que cela devrait le faire, bien que je ne sois pas familier avec la construction pred1(pred2(...)...) :- ... (mon Prolog est très rouillé).

eval(A, A) :- number(A).
eval(plus(A, B), R) :- eval(A, A_R), eval(B, B_R), R is A_R+B_R.

Réponse populaire

Voir ici un autre schéma exploitant DCG et (une sorte de) évaluation paresseuse:

/*
File:    dcg_calculator.pl
Author:  Carlo,,,
Created: Aug 16 2011
Purpose: associativity and precedences in calculator
*/

:- module(dcg_calculator, [dcg_calculator/2, expr//1]).
%- [library(http/dcg_basics)]. obsolete
:- [library(dcg/basics)].

/* usage

?- dcg_calculator("1+(-2-2)",S),V is S.
S = 1+ (-2-2),
V = -3 ;
false.

*/
dcg_calculator(Formula, IsEvaluable) :-
    phrase(expr(IsEvaluable), Formula, []).

expr(Evaluable) -->
    sum(Evaluable).

sum(S) -->
    product(P), sum_1(P, S).
sum_1(L, S) -->
    "+", product(P), sum_1(L + P, S);
    "-", product(P), sum_1(L - P, S);
    {L = S}.

product(P) -->
    value(V), product_1(V, P).
product_1(V, P) -->
    "*", value(U), product_1(V * U, P);
    "/", value(U), product_1(V / U, P);
    {V = P}.

% value(V) -->
%   {var(V)} -> {V=0 /* between(0, 9, V)*/ }, "0".

value(V) -->
    "(", expr(V), ")" ;
    number(V).

Utiliser des grammaires pour modéliser les structures de données est une technique très utile dans Prolog. La grammaire utilisée est une implémentation de PEG . La dépendance de SWI-Prolog est très limitée, numéro // 1 seulement.



Sous licence: CC-BY-SA with attribution
Non affilié à Stack Overflow
Est-ce KB légal? Oui, apprenez pourquoi
Sous licence: CC-BY-SA with attribution
Non affilié à Stack Overflow
Est-ce KB légal? Oui, apprenez pourquoi