Domanda
Sto cercando un modo per costruire un albero delle espressioni in Prolog. Ho già fatto alcuni esperimenti e ho trovato il seguente codice di lavoro (che gestirà solo le costanti e l'espressione più):
const(_).
plus(_, _).
eval(const(R), R).
eval(plus(A, B), R) :- number(A), number(B), R is A+B.
eval(plus(A, B), R) :- number(A), eval(B, B_R), R is A+B_R.
eval(plus(A, B), R) :- eval(A, A_R), number(B), R is A_R+B.
eval(plus(A, B), R) :- eval(A, A_R), eval(B, B_R), R is A_R+B_R.
C'è un'alternativa più semplice a questo approccio? Dovrò definire questi 4 casi per ciascuno degli operatori che ho intenzione di aggiungere al mio programma?
Risposta accettata
Penso che questo dovrebbe farlo, anche se non ho familiarità con il costrutto pred1(pred2(...)...) :- ... (il mio Prolog è molto arrugginito).
eval(A, A) :- number(A).
eval(plus(A, B), R) :- eval(A, A_R), eval(B, B_R), R is A_R+B_R.
Risposta popolare
Vedi qui un altro schema, sfruttando DCG e (una sorta di) valutazione pigra:
/*
File: dcg_calculator.pl
Author: Carlo,,,
Created: Aug 16 2011
Purpose: associativity and precedences in calculator
*/
:- module(dcg_calculator, [dcg_calculator/2, expr//1]).
%- [library(http/dcg_basics)]. obsolete
:- [library(dcg/basics)].
/* usage
?- dcg_calculator("1+(-2-2)",S),V is S.
S = 1+ (-2-2),
V = -3 ;
false.
*/
dcg_calculator(Formula, IsEvaluable) :-
phrase(expr(IsEvaluable), Formula, []).
expr(Evaluable) -->
sum(Evaluable).
sum(S) -->
product(P), sum_1(P, S).
sum_1(L, S) -->
"+", product(P), sum_1(L + P, S);
"-", product(P), sum_1(L - P, S);
{L = S}.
product(P) -->
value(V), product_1(V, P).
product_1(V, P) -->
"*", value(U), product_1(V * U, P);
"/", value(U), product_1(V / U, P);
{V = P}.
% value(V) -->
% {var(V)} -> {V=0 /* between(0, 9, V)*/ }, "0".
value(V) -->
"(", expr(V), ")" ;
number(V).
Usare le grammatiche per modellare le strutture dati è una tecnica molto utile in Prolog. La grammatica utilizzata è un'implementazione di PEG . Dipendenza da SWI-Prolog è molto limitata, solo numero // 1.
Autorizzato sotto: CC-BY-SA with attribution
Non affiliato con Stack Overflow